Patrick Elliott <sel### [at] rraznet> wrote:
<snip>
> This is quite different than manually changing lines of code,
<snip>
> have to plug in the ones you had right, then run it again, with
> different variances. Kind of annoying, even if it is feasible.
<snip>
> especially when you don't want to spend a lot of time fiddling,
<snip>
Well.. It's hard to explain, but I belive those points are one of the main
reasons why I like POV-Ray so much. A little tweaking here, and a little there,
full control over what happens in your scene (hopefully ;) and you get what you
want in the end.

> having to hit "run"
If you don't like clicking "Run" you can press Alt+G, I find it saves a lot of
time while tweaking ;)

Try out Jpatch - http://www.jpatch.com/ - It has a very nice material editor
with a lot of sliders for pigment and finish which puts out pure, clean POV-Ray
code.

KPovModeler might also be an alternative if you run Linux, -
http://www.kpovmodeler.org/

Or you could use the provided code to do a real time preview in POV-Ray. Sorry,
I couldn't resist. :P
Jokes aside, I trie to quickly put togehter that dice you wanted, but it turned
out to be a bit harder to make it with rounded corners than I thought. It was
easy making it in Wings 3D and uv mapping it though ;)

-Peter

// POV-Ray does REAL TIME TEXTURE PREVIEW!!
// (Requires POV-Ray 3.7 beta)
// Command line options:
// +kla +rtr +w160 +h120 -a

#local SPC = 0.01; // [0.001-1] lower makes more spheres
#local Fancy_Stuff = off; // Turn impractical eye candy on or off
#local Use_Hdr = off; // Requires hdr_env.hdr from megapov present

#local Translate = 4/SPC;

#local Cam = 0;
#while (Cam <=1)
camera{
        location z*-10 look_at 0 angle 25  translate x*Cam*Translate
}
#local Cam = Cam+SPC;
#end

light_source{<Translate/3,Translate*0.1,-Translate*1.5>,1}

#local X = 0;
#while (X <= 1)
        sphere{0,1
                no_shadow
                pigment {rgb <1,0.6,0.5>}
                normal {granite 0.6 scale 5 turbulence X}
                finish {phong 0.2 specular 0.4 reflection 0.2*Fancy_Stuff}
        rotate X*360*Fancy_Stuff
        translate x*X*Translate
        }
        text{ttf "arial.ttf"
                concat("Value: ",str(X,3,3)),0.1,0
                pigment {rgb y*1+<0.3,0,1>*Fancy_Stuff}
                finish {reflection Fancy_Stuff*0.2}
                rotate <sin(X*pi)*50,sin(X*pi)*30,0>*Fancy_Stuff
                scale 0.5 translate <-1.33,-1.5+Fancy_Stuff*0.1,0>
        translate x*X*Translate
        }
#local X = X+SPC;
#end

#if(Fancy_Stuff & Use_Hdr)
sphere {
  0,1
  pigment { image_map { hdr "hdr_env.hdr" once interpolate 2 map_type 1 } }
  finish { ambient 0.8 diffuse 0 }
  scale <-1,1,1>*Translate*2
  hollow
}
#end

Post a reply to this message